游戏《魔兽世界：无限》牧师宏分为治疗、驱散、增益与复活、控制与打断、输出、种族专属、更多以及练级常用等类别，这份攻略整理了全套宏代码，按分页划分，玩家可按需查找、直接复制使用。

魔兽世界无限治疗牧师宏命令

治疗术鼠标指向，Shift 快速治疗

16级可用

给鼠标指向 / 友方目标 / 自己治疗术；Shift 改快速治疗。

#showtooltip

/cast [mod:shift,@mouseover,help,nodead][mod:shift,help,nodead][mod:shift,@player] 快速治疗; [@mouseover,help,nodead][help,nodead][@player] 治疗术

次级治疗术鼠标指向或自己

1级可用

用最高等级次级治疗术奶鼠标指向 / 友方目标 / 自己。

#showtooltip 次级治疗术

/cast [@mouseover,help,nodead][help,nodead][@player] 次级治疗术

恢复鼠标指向或自己

8级可用

给鼠标指向 / 友方目标 / 自己上恢复。

#showtooltip 恢复

/cast [@mouseover,help,nodead][help,nodead][@player] 恢复

真言术：盾 鼠标指向或自己

6级可用

给鼠标指向 / 友方目标 / 自己上盾。

#showtooltip 真言术：盾

/cast [@mouseover,help,nodead][help,nodead][@player] 真言术：盾

心灵专注 + 快速治疗

20级可用

开心灵专注再快速治疗鼠标指向 / 友方目标 / 自己，不耗蓝且更容易暴击。

#showtooltip 心灵专注

/cast 心灵专注

/cast [@mouseover,help,nodead][help,nodead][@player] 快速治疗

治疗祷言（鼠标指向的小队）

30级可用

对鼠标指向 / 友方目标 / 自己所在小队放治疗祷言。

#showtooltip 治疗祷言

/cast [@mouseover,help,nodead][help,nodead][@player] 治疗祷言

苦修鼠标指向（敌我通用）

30级可用

鼠标下是友方就奶、敌方就打；没指着就用目标。

#showtooltip 苦修

/cast [@mouseover,help,nodead][@mouseover,harm,nodead][] 苦修

心灵专注 + 治疗祷言

需要点出心灵专注；暗影形态要先解除。

#showtooltip 心灵专注

/cast 心灵专注

/cast 治疗祷言

治疗祷言（自动退暗影形态）

以自己为中心的群体治疗，不是鼠标目标技能。

#showtooltip 治疗祷言

/cancelaura 暗影形态

/cast 治疗祷言

联结治疗（鼠标指向优先）

25级可用

治别人的同时回自己；暗影形态会自动解除。

#showtooltip 联结治疗

/cancelaura 暗影形态

/cast [@mouseover,help,nodead][] 联结治疗

快速治疗，Shift 防护恐惧结界

先解除暗影形态再治疗；Shift 提前给关键目标防恐。

#showtooltip [mod:shift] 防护恐惧结界; 快速治疗

/cancelaura [nomod:shift] 暗影形态

/cast [mod:shift,@mouseover,help,nodead] 防护恐惧结界; [mod:shift,help,nodead] 防护恐惧结界; [@mouseover,help,nodead][] 快速治疗